Syntax
  take = take (o)
    Where o Isa object
      Else "You cannot take that."

Syntax
  drop = drop (o)
    Where o Isa object
      Else "You cannot drop that."

Syntax
  light = light (o)
    Where o Isa object
      Else "You cannot light that."

Syntax
  extinguish = extinguish (o)
    Where o Isa object
      Else "You cannot extinguish that."


The hero Isa actor
  Container
End The hero.


Add To Every object
  Is Not lightsource.

  Verb take
    Check o Not In hero
      Else 
        "You already have that."
    Does
      Locate o In hero.
  End Verb.

  Verb drop
    Check o In hero
      Else 
        "You don't have that."
    Does
      Locate o Here.
  End Verb.
End Add To.

Add To Every location
  Is
    lit.
End Add To.

Syntax
  'look' = l.

Verb 'look'
  Does
    If Count Isa object, Is lightsource, Here = 0
      And Current Location Is Not lit Then
      "You cannot see anything without any light."
    Else
      Look.
    End If.
End Verb.

Syntax
  i = i.

Verb i
  Does
    List hero.
End Verb.


The indoors Isa location
  Is 
    Not lit.
  Description
    If Count Isa object, Is lightsource, Here > 0 Then
      "This is usually a very dark room. But in this light you can see..."
    Else 
      "You can not see anything in the dark."
    End If.
  Exit out To outdoors.
End The indoors.

The outdoors Isa location
  Description
    "Out here in the sun you can see everything."
  Exit 'in' To indoors.
End The outdoors.

The lamp Isa object
  At outdoors
  Description
    "There is a lamp here."
    If This Is lightsource Then
      "It is providing light."
    Else
      "You'll have to light it to get some light from it."
    End If.

  Verb light
    Does
      Make lamp lightsource.
      Look.
  End Verb.

  Verb extinguish
    Does
      Make lamp Not lightsource.
      If Count Isa object, Is lightsource, Here = 0
        And Current Location Is Not lit Then
        "It is now pitch black."
      End If.
  End Verb.      
  
End The lamp.

Start At outdoors.
  "Try moving 'in' and 'out' with and without the lamp. You can light the
   lamp and drop it. Also try 'look' in various situations."